看看我发在4楼的代码,应该已经给你解决了.符合条件的是418条记录吧.

CLOSE DATABASES ALL 
USE 表9 ALIAS b9 IN 0
USE 表10 ALIAS b10 IN 0
SELECT b10
ZAP 
SELECT z59, z60, z61, z62, z63, z64, z65, z66, z67, z68, z69 FROM 表8 WHERE RECNO() = RECCOUNT() INTO ARRAY a8

SELECT b9
SCAN
    SCATTER FIELDS z59, z60, z61, z62, z63, z64, z65, z66, z67, z68, z69 TO a9
    LOCAL a10[1, 14]
    a10 = 0
    a10[1, 1] = h1
    a10[1, 2] = h2
    a10[1, 3] = h3
    ok = 0
    FOR i = 1 TO 11
        IF ASCAN(a9, a8[i]) > 0
            ok = 1
            EXIT 
        ENDIF 
    ENDFOR 
    IF ok = 1
        LOOP 
    ENDIF 
    FOR i = 1 TO 11
        IF a9[i] != a8[i]
            a10[1, i + 3] = a9[i]
        ENDIF 
    ENDFOR 
    INSERT INTO 表10 FROM ARRAY a10
ENDSCAN 
SELECT b10
BROWSE 

从表9取数放到表10,好像没说清楚表9与表10的数据记录关系，因每次取出的数据记录是不同的。
假设以H1、H2和H3作为表9与表10的数据记录对应关系测试，不知有无理解错，没校对。

CREATE CURSOR tt (zs I)
USE 表8 IN 0 ALIAS t8
USE 表9 IN 0 ALIAS t9
USE 表10 IN 0 ALIAS t10
SELECT t10
ZAP
APPEND FROM DBF("t9") FIELDS H1,H2,H3
INDEX on STR(H1,1)+STR(H2,1)+STR(H3,1) TAG h1h2h3
SELECT t8
GO BOTTOM
SCATTER FIELDS z59,z60,z61,z62,z63,z64,z65,z66,z67,z68,z69 TO a8
DIMENSION a8[11,1]
SELECT tt
APPEND FROM ARRAY a8
FOR i=59 TO 69
    cmd = "SELECT H1,H2,H3,z"+TRANSFORM(i)+" FROM t9 WHERE z"+TRANSFORM(i)+" NOT in (SELECT zs FROM tt) INTO CURSOR tmp"
    EXECSCRIPT(cmd)
    SELECT tmp
    SET RELATION TO STR(H1,1)+STR(H2,1)+STR(H3,1) INTO "t10"
    cmd = "REPLACE t10.z"+TRANSFORM(i)+" WITH tmp.z"+TRANSFORM(i)+" ALL"
    EXECSCRIPT(cmd)
    SET RELATION TO
ENDFOR
SELECT * FROM t10
CLOSE DATABASES ALL
RETURN

用 UPDATE - SQL
CREATE CURSOR tt (zs I)
USE 表8 IN 0 ALIAS t8
USE 表9 IN 0 ALIAS t9
USE 表10 IN 0 ALIAS t10
SELECT t10
ZAP
APPEND FROM DBF("t9") FIELDS H1,H2,H3
SELECT t8
GO BOTTOM
SCATTER FIELDS z59,z60,z61,z62,z63,z64,z65,z66,z67,z68,z69 TO a8
DIMENSION a8[11,1]
SELECT tt
APPEND FROM ARRAY a8
FOR i=59 TO 69
    cmd = "SELECT H1,H2,H3,z"+TRANSFORM(i)+" FROM t9 WHERE z"+TRANSFORM(i)+" NOT in (SELECT zs FROM tt) INTO CURSOR tmp"
    EXECSCRIPT(cmd)
    cmd = "UPDATE t10 SET t10.z"+TRANSFORM(i)+"=tmp.z"+TRANSFORM(i)+" FROM tmp WHERE tmp.H1=t10.H1 AND tmp.H2=t10.H2 AND tmp.H3=t10.H3"
    EXECSCRIPT(cmd)
ENDFOR
SELECT * FROM t10
CLOSE DATABASES ALL
RETURN

厨师王德榜老师你好！
你写的程序已在VF中运行，很好。有的地方看不懂，今后继续学习。

吹水佬老师，你好！
你的两个程序都看了，有些地方不懂。
运行没有问题，但运行结果不是我想要的。是我没说清楚。
不等于的保留，等于的就应删除，因此运行结果应少于1000行。
sdta,厨师王德榜2位的程序运行后是418行。
再次感谢老师的帮助！
以后有问题还要请教老师。

吹水佬老师，你好！
你写的2个程序都看了，有一些地方看不懂。
程序运行没有问题，但结果不是我想要的。是我没有说清楚。
不等于的保留，等于的删除，因此结果应少于1000行。
sdta,厨师王德榜，两位的程序运行后是418行。
非常感谢老师的多次帮助。以后有问题还要请教老师。

我是不等的保留，相等的请空。
或者我理解错了，有点不明？
假如表9同一记录的z59相等而z60不等，当比对z59时删除这条记录，是不是会漏掉z60不等这记录？

* 利用楼2的思路

CLOSE DATABASES 
USE 表8 ALIAS B8 IN 0
USE 表9 ALIAS B9 IN 0
USE 表10 ALIAS B10 IN 0

*!* 查找动态比对参数
SELECT t0.Qihao,z59,z60,z61,z62,z63,z64,z65,z66,z67,z68,z69 FROM B8 AS t0 ;
RIGHT JOIN (SELECT NVL(MAX(Qihao),0) as Qihao FROM B8) AS  t1 ON t0.Qihao=t1.Qihao ;
INTO ARRAY a8

*!* 拼接动态比对条件
LOCAL s1,ii
s1=TRANSFORM(a8[1,2])
FOR ii=3 TO 12
    s1 = s1 + "," + TRANSFORM(a8[1,ii])
ENDFOR

*!* 查询过滤新数据
SELECT H1,H2,H3,z59,z60,z61,z62,z63,z64,z65,z66,z67,z68,z69 FROM b9 WHERE ;

 !INLIST(z59,&s1) AND ;

 !INLIST(z60,&s1) AND ;

 !INLIST(z61,&s1) AND ;

 !INLIST(z62,&s1) AND ;

 !INLIST(z63,&s1) AND ;

 !INLIST(z64,&s1) AND ;

 !INLIST(z65,&s1) AND ;

 !INLIST(z66,&s1) AND ;

 !INLIST(z67,&s1) AND ;

 !INLIST(z68,&s1) AND ;

 !INLIST(z69,&s1) INTO ARRAY a9

*!* 生成新的表10数据
SELECT b10
ZAP 
APPEND FROM ARRAY a9
BROWSE