这样的数据

你不是说用表速度慢吗，怎么现在想用表了。

不是，这是导出之后的结果，我的意思是带后边的文件信息。

获取的数据还存在数组中，到最后可以写到文件表里或者做其他用途。

生成的文件表加个备注字段保存文件属性信息
......
? nCountF,"个文件", nCountD,"个文件夹", nCountE,"个文件夹搜索出现异常"
CREATE CURSOR tt (FileName V(240), FileInfo M)
IF nCountF > 0
    DIMENSION arrFile[nCountF,1]
    APPEND FROM ARRAY arrFile  
    REPLACE FileInfo WITH _GetFileInfo(FileName) ALL IN "tt"
    GO TOP
    BROWSE
ENDIF

FUNCTION _GetFileInfo(cFileName)
    ** 获取文件信息
    ** cRet = 文件信息
    RETURN cRet
ENDFUNC

谢谢！明天根据19楼思路再次优化我的代码！？看看效果！

可以用SHLL获取文件的详细信息，但速度有点慢。
示例：
oShell = CREATEOBJECT("Shell.Application")
_GetFileInfo(oShell, GETFILE())
RETURN

FUNCTION _GetFileInfo(oShell, cFileName)
    IF !FILE(cFileName)
        RETURN ""
    ENDIF
    LOCAL oFolder, oFolderItem
    LOCAL i, cName, cValue
    oFolder = oShell.Namespace(JUSTPATH(cFileName))
    IF oFolder==NULL
        RETURN ""
    ENDIF
    oFolderItem = oFolder.ParseName(JUSTFNAME(cFileName))
    FOR i=0 TO 330
        cName = oFolder.GetDetailsOf(NULL, i)
        IF !EMPTY(cName)
            cValue = oFolder.GetDetailsOf(oFolderItem, i)
            IF !EMPTY(cValue)
                ? TRANSFORM(i) + "." + cName + " : " + cValue
            ENDIF
        ENDIF
    ENDFOR
ENDFUNC

谢谢吹版！这么早！

AGETFILEVERSION()函数可以获取文件版本信息，不用麻烦！

[此贴子已经被作者于2018-7-26 08:35编辑过]

何必搞这么复杂，直接用 windows 的 dir 命令，速度也不比用 win32api 慢多少，代码简单明了，基本不用考虑错误处理
要是嫌黑窗口不好看，用木瓜myfll中的函数隐藏运行就好

Function ScanFile3(cDrv)
    Local ss, cmd, temp
    ss = Seconds()
    Set Library To myfll.fll
    temp = sys(2015) + '.txt'
    cmd = '/c dir ' + cDrv + ' /s/a:-d/b >' + temp
    ShellExecWait('cmd', cmd, 0)
    Create Cursor sf3 (name V(250))
    Append From (temp) sdf
    Erase (temp)
    ? Textmerge(' <<cDrv>>   找到 <<Recc()>> 个文件，耗时 <<Seconds()-ss>> 秒')
EndFunc

要获取详细点的信息，加一倍左右的时间

Function ScanFile3(cDrv)
    Local ss, cmd, temp, nd, cExact
    ss = Seconds()
    temp = sys(2015) + '.txt'
    cmd = '/c dir ' + cDrv + ' /s/a/-c/o:gn >' + temp
    Set Library To myfll.fll
    ShellExecWait('cmd', cmd, 0)
    Create Cursor sf3 (date C(12), time C(9), size C(15), name V(250))
    Append From (temp) sdf
    Erase (temp)
    Select Cast(date as D) date, Cast(time as C(5)) time, Cast(Alltrim(size) as V(10)) size, name ;
        from sf3 where (date not Like ' %') and (name not in ('.', '..')) into cursor sf3
    cExact = Set("Exact")
    Set Exact off
    Count to nd for size = '<'
    Set Exact &cExact
    ? Textmerge(' <<cDrv>>   <<Recc()-nd>> 个文件，<<nd>> 个文件夹，耗时 <<Seconds()-ss>> 秒')
EndFunc

[此贴子已经被作者于2018-7-26 13:11编辑过]

楼上的兄弟，你提供结果的格式不是我想要的，但是速度确实快了。你的代码能不能实现我要的结果？

修改后，好像也不快！但是确实循环的次数少了，但是数组多了，占用内存的数量增加。

********************************************************************************
***功能：遍历指定盘符下的所有文件及文件夹，并获取所有相关信息。
***文件名：ScanFileTol.Prg
***调用格式：ScanFileTol('D:')
********************************************************************************
PARAMETERS cDrvmc
cDrvmc=UPPER(ALLTRIM(cDrvmc))
nOldsec=SECONDS()
?
? '[ '+cDrvmc+' ]开始扫描...',DATETIME()
DIMENSION MyarrDir(1,5),MyarrFile(1,5),MyarrErr(1)
MyarrDir(1,1)=ADDBS(cDrvmc)
MyarrDir(1,2)=''
MyarrDir(1,3)=DATE()
MyarrDir(1,4)=TIME()
MyarrDir(1,5)='....D'
STORE 1 TO nCountDir
STORE 0 TO nCountFile,nCountErr
nIarr=1
DO WHILE nIarr<=nCountDir
   nNum=ADIR(Myarrtmp,MyarrDir(nIarr,1)+'*.*','RASHD')
   IF nNum < 1
      nCountErr = nCountErr + 1
      DIMENSION MyarrErr[nCountErr]
      MyarrErr[nCountErr] = "Error:" + MyarrDir(nIarr,1)
   ELSE
      FOR I=IIF(nIarr<=1,1,3) TO nNum
          IF 'D'$Myarrtmp(I,5)
             Myarrtmp(I,1)=MyarrDir(nIarr,1)+Myarrtmp(I,1)+'\'
             nCountDir=nCountDir+1
             DIMENSION MyarrDir(nCountDir,5)
             FOR ai=1 TO 5
                 MyarrDir(nCountDir,ai)=Myarrtmp(i,ai)
             ENDFOR
          ELSE
             Myarrtmp(I,1)=MyarrDir(nIarr,1)+Myarrtmp(I,1)
             nCountFile=nCountFile+1
             DIMENSION MyarrFile(nCountFile,5)
             FOR ai=1 TO 5
                 MyarrFile(nCountFile,ai)=Myarrtmp(i,ai)
             ENDFOR
          ENDIF
      ENDFOR
   ENDIF
   nIarr=nIarr+1
ENDDO
? '[ '+cDrvmc+' ]扫描完成...',DATETIME()
? '[ '+cDrvmc+' ]共找到[ '+TRANSFORM(nCountFile+nCountDir)+' ]个对象，其中文件[ '+TRANSFORM(nCountFile)+' ]个，文件夹[ '+TRANSFORM(nCountDir)+' ]个！用时[ '+TRANSFORM(SECONDS()-nOldsec)+' ]秒！'
CREATE CURSOR Mydbf (wjmc C(254),wjcd N(20),wjrq D,wjshj C(10),wjsx C(6))
APPEND FROM ARRAY MyarrDir
APPEND FROM ARRAY MyarrFile
APPEND FROM ARRAY MyarrErr

[此贴子已经被作者于2018-7-27 08:11编辑过]

收藏，学习了，谢谢